Re: Files with Empty members

[Bill Robins <brobins@xxxxxxxxxxxxx>]

Lenny,

Here is a utility you may be able to use:
---------------------------------------------------------------------------------------------------------------------

             PGM        PARM(&FLIB &FTYPE)

             DCLF       FILE(QAFDMBR)
             DCL        VAR(&FLIB) TYPE(*CHAR) LEN(10)
             DCL        VAR(&FTYPE) TYPE(*CHAR) LEN(5)
             DCL        VAR(&SBMTTD) TYPE(*CHAR) LEN(1)

             RTVJOBA    TYPE(&SBMTTD)
             IF         COND(&SBMTTD *EQ '1') THEN(DO)
             SBMJOB     CMD(CALL PGM(MISLIB/RMVDUPMBRS) PARM(&FLIB +
                          &FTYPE)) JOB(RMVDUPMBRS) JOBQ(QPGMR) +
                          JOBPTY(7)
             RETURN
             ENDDO

             DSPFD      FILE(&FLIB/*ALL) TYPE(*MBR) OUTPUT(*OUTFILE) +
                          FILEATR(&FTYPE) OUTFILE(QTEMP/MBR)

             OVRDBF     FILE(QAFDMBR) TOFILE(QTEMP/MBR)

 LOOP1:
              RCVF
              MONMSG     MSGID(CPF0864) EXEC(GOTO CMDLBL(ENDLOOP1))

              IF         COND(&MBDTAT = 'S') THEN(GOTO CMDLBL(LOOP1)) +
                           /* Skip Source Files */
              IF         COND(&MBNRCD > 0) THEN(GOTO CMDLBL(LOOP1))
              IF         COND(&MBNOMB = 1) THEN(GOTO CMDLBL(LOOP1))
              IF         COND(&MBNAME = &MBFILE) THEN(GOTO +
                           CMDLBL(LOOP1))
              IF         COND(&MBNAME = 'BACKFLUSH ') THEN(GOTO +
                           CMDLBL(LOOP1))
              IF         COND(&MBNAME = 'LOG ') THEN(GOTO CMDLBL(LOOP1))
              IF         COND(&MBNAME = 'MRP540 ') THEN(GOTO +
                           CMDLBL(LOOP1))
              IF         COND(&MBNAME = 'QUOTE ') THEN(GOTO +
                           CMDLBL(LOOP1))
              IF         COND(&MBNAME = 'RETURN ') THEN(GOTO +
                           CMDLBL(LOOP1))
              IF         COND(&MBNAME = 'RLSWIP ') THEN(GOTO +
                          CMDLBL(LOOP1))
             IF         COND(&MBNAME = 'WORK ') THEN(GOTO +
                          CMDLBL(LOOP1))
             IF         COND(%SST(&MBNAME 1 2) = 'XX') THEN(GOTO +
                          CMDLBL(LOOP1))

             RMVM       FILE(&MBLIB/&MBFILE) MBR(&MBNAME)
             MONMSG     MSGID(CPF7310 CPF0000)
             GOTO       CMDLBL(LOOP1)

ENDLOOP1:

 END:        ENDPGM
------------------------------------------------------------------------------------------------------------

If you know your programming, you can make changes as necessary.

Bill


MrLennyB@aol.com wrote:

> With BPCS V4.0.4, several files, such as ECH, ECL, FSO, FOD, FMA , etc.
> have empty members.
>
> Does anyone know of an orderly way to delete these empty members.  I have
> looked through the System Reorg programs and it doesn't appear that BPCS has a
> program to satisfy this function.  Any help would be appreciated.
>
> Thanks
>
> Lenny Bellott
> Shop-Vac Corp.

+---
| This is the BPCS Users Mailing List!
| To submit a new message, send your mail to BPCS-L@midrange.com.
| To subscribe to this list send email to BPCS-L-SUB@midrange.com.
| To unsubscribe from this list send email to BPCS-L-UNSUB@midrange.com.
| Questions should be directed to the list owner: dasmussen@aol.com
+---