Re: CEEDAYS

[Jon.Paris@xxxxxx]

This example includes a number of the CEE APIs - no need for anything
special when compiling.

       PROCESS NOMONOPRC.

       IDENTIFICATION DIVISION.
       PROGRAM-ID. CEEDATES.
       ENVIRONMENT DIVISION.
       CONFIGURATION SECTION.
         SPECIAL-NAMES.
         LINKAGE TYPE PROCEDURE FOR "CEEDAYS" USING ALL DESCRIBED,
         LINKAGE TYPE PROCEDURE FOR "CEEDYWK" USING ALL DESCRIBED,
         LINKAGE TYPE PROCEDURE FOR "CEEDATE" USING ALL DESCRIBED.

       DATA DIVISION.

       WORKING-STORAGE SECTION.

       77  Lilian-Date         Pic S9(9)  BINARY.
       77  Day-of-Week-Numeric Pic S9(9)  BINARY.
       77  Day-of-Week-Alpha   Pic X(10).
       77  Today               Pic 9(8).
       77  Today-Edit          Pic X(4)/X(2)/X(2).
       77  YYMD-Format         Pic X(8)          VALUE "YYYYMMDD".
       77  Day-of-Week-Format  Pic X(10)         VALUE "Wwwwwwwwwz".

       PROCEDURE DIVISION.
       SAMPLE.

           Accept Today From DATE YYYYMMDD.

           Move Today   to   Today-Edit.

           CALL "CEEDAYS" USING Today
                                YYMD-Format
                                Lilian-Date
                                OMITTED.

           CALL "CEEDYWK" USING Lilian-Date
                                Day-of-Week-Numeric
                                OMITTED.

           CALL "CEEDATE" USING Lilian-Date
                                Day-of-Week-Format
                                Day-of-Week-Alpha
                                OMITTED.

           Display "Today is ", Today-Edit, "   Day number ",
                   Day-of-Week-Numeric, "   Alpha value ",
                   Day-of-Week-Alpha, "   Lilian date " Lilian-Date.


           STOP RUN.

+---
| This is the COBOL/400 Mailing List!
| To submit a new message, send your mail to COBOL400-L@midrange.com.
| To subscribe to this list send email to COBOL400-L-SUB@midrange.com.
| To unsubscribe from this list send email to COBOL400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---END