RE: PING in a CL-program

[Ed Doxtator <DOC@xxxxxxxxxxxxxxxxxxxx> (by way of David Gibbs <david@xxxxxxxxxxxx>)]

>Hello

>I am trying to check if another host is active in batch mode. I am using
>PING. How can I determine if I get the message TCP3206 in a CL-program?

>Greatful for any help.

>Staffan Lofberg

Staffan:

You can do a receive message (RCVMSG) command after the PING, like in   
this example:

PGM  PARM(&RMTSYS)
                                                            

DCL         VAR(&MSGID)  TYPE(*CHAR)  LEN(7)
DCL         VAR(&RMTSYS) TYPE(*CHAR)  LEN(20)
                                                            

            PING RMTSYS(&RMTSYS)
                                                            

LOOP:
            RCVMSG MSGQ(*PGMQ) MSGID(&MSGID)
            IF COND(&MSGID *EQ ' ') +
            THEN(DO)
               GOTO CMDLBL(OK)
            ENDDO
                                                            

            IF COND(&MSGID *EQ 'TCP3206') +
            THEN(DO)
               SNDPGMMSG MSG('PING FAILED.') TOPGMQ(*PRV)
               GOTO CMDLBL(ENDIT)
            ENDDO
            ELSE CMD(DO)
               GOTO CMDLBL(LOOP)
            ENDDO
                                                            

OK:
            SNDPGMMSG MSG('PING SUCCEEDED!') TOPGMQ(*PRV)
                                                            

ENDIT:
ENDPGM

The logic is pretty straightforward-- after the RCVMSG, if the MSGID is   
blank, no messages exist in the message queue, and PING succeeded.  If   
the MSGID is TCP3206, then PING failed.  If the MSGID is anything else,   
go back and get another message.

Hope this helps.

 -Doc  


* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
* This is the Midrange System Mailing List!  To submit a new message,   *
* send your mail to "MIDRANGE-L@midrange.com".  To unsubscribe from     *
* this list send email to MAJORDOMO@midrange.com and specify            *
* 'unsubscribe MIDRANGE-L' in the body of your message.  Questions      *
* should be directed to the list owner / operator: david@midrange.com   *
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *