Re: How to identify different Logical Partitions

[Mlpolutta@xxxxxxx]

There is no command.  This program should demonstrate the trick, though.

H DFTACTGRP(*NO) ACTGRP(*CALLER)                            
H OPTION(*SRCSTMT:*NODEBUGIO)                               
                                                            
DMatMAtr          PR                  EXTPROC('_MATMATR1')  
D                                 *   VALUE                 
D                                2    CONST                 
                                                            
 * Working variables for Materialize                        
DAttribPtr        s               *   inz(%addr(Attributes))
DMatOption        s              2    inz(x'01E0')          
                                                            
 * Receiver variable for Materialize                        
DAttributes       DS           512                          
D BytPrv                        10i 0                       
D BytAvl                        10i 0                       
D NumParts                       3u 0                       
D CurPart                        3u 0                       
D PriPart                        3u 0                       
D Reserved                       5                          
D LogSerial                     10                          
D Reserved2                      5   
D PartShrPrcAtr                  1   
D MinPrc                         5u 0
D MaxPrc                         5u 0
D CurPrc                         5u 0
D Reserved3                      2   
D CfgMinMem                     10u 0
D CfgMaxMem                     10u 0
D CurAvlMem                     10u 0
D MinPctInt                      3u 0
D MaxPctInt                      3u 0
D CurPctInt                      3u 0
D Reserved4                      1   
D ConnAtr                        2   
D OptAtr                         2   
D MinPrcCap                     10u 0
D MaxPrcCap                     10u 0
D CurPrcCap                     10u 0
D CurAvlPrcShr                  10u 0
D NumPrcShr                      5u 0
D Reserved5                      2   
                                                               
 * Set Bytes Provided to size of Receiver Variable (Attributes)
C                   eval      BytPrv = %size(Attributes)       
                                                               
 * Use MATMATR MI instruction                                  
C                   callp     MatMAtr(AttribPtr: MatOption)    
                                                               
 * Determine if information returned                           
C                   if        BytAvl >= 56                     
                                                               
 * display configured active partitions                        
C     NumParts      dsply                                      
                                                               
 * display current partition                                   
C     CurPart       dsply                                      
                                                               
 * display current interactive percentage                      
C     CurPctInt     dsply                                      
                                                               
C                   else                                       
C     'Error  '     dsply                
C                   endif                
                                         
 * Shut down, go home                    
C                   eval      *inlr = '1'
C                   return               

> Greetings, 
> 
> Apologies if I phrase this incorrectly but I am not that
> technical-minded!
> 
> Is there a command to identify the serial number or ID of the various
> LPARS configured on an iSeries?
> 
> I know to retrieve the serial number one keys in DSPSYSVAL 
> QSRLNBR, is
> there a similar command?
> 
> Many thanks 
> 
> Jamie Coles