Re: Display file puzzlement

[Simon Coulter <shc@xxxxxxxxxxxxxxxxx>]

On 22/04/2008, at 4:02 AM, John McKee wrote:
> I removed PUTOVR, OVRATR, and OVRDTA.  Still no RI capability.  With
> the ERRSFL,
> though, I guess I can live with it.

You can have these keywords in the file as long as they are not  
active at the same time as ERRMSG. It appears that ERRMSG takes  
precedence. In all these cases the correct analysis is to create a  
test-case that does what you want to determine exactly where the  
problem lies without all the application rubbish getting in the way.

Try the following:

DSPF TSTERRSFLD
*************** Beginning of data  
********************************************
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CA03(03 'Exit')
     A                                      ERRSFL
     A          R THEFORMAT
     A                                  1 35'Test ERRSFL'
     A                                      DSPATR(HI)
     A                                  3  2'Type bad data, press  
Enter.'
     A                                      COLOR(BLU)
     A                                  5  5'Have a go ya  
mug . . . . . . .'
     A            DATA1         10   B  5 37
     A  98                                  ERRMSG('Bzzt! Wrong  
answer!' 98)
     A                                  7  5'Have another  
go  . . . . . . .'
     A            DATA2         10   B  7 37
     A  99                                  ERRMSG('Bzzt! Wrong  
again!' 99)
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
****************** End of data  
***************************************************

RPGLE TSTERRSFLR
*************** Beginning of data ***********************************
FTSTERRSFLDCF   E             WORKSTN
C                   EXFMT     THEFORMAT
C                   SETON                                        9899
C                   DOU       *IN03 = *ON
C                   EXFMT     THEFORMAT
C                   ENDDO
C                   SETON                                        LR
****************** End of data **************************************

Compile the display file and the RPG. Call the RPG. Press Enter. You  
should see both input fields reverse-imaged, the cursor should be in  
the first field, both error messages should be displayed in the error  
sub-file at the bottom of the screen.

If this is not happening for you then:
	1) Check the settings in your emulator--it is possible that RI is  
mapped to something else
	2) If not using PC5250 then start using it
	3) Check the parameters on the CRTDSPF command are the IBM-shipped ones
	4) Check the device type being emulated--it is possible that you are  
emulating a device without RI capability (though unlikely)
	5) Check for PTFs--perhaps the 5250 data stream is wrong (again  
unlikely)

I expect that my example code will work correctly indicating the  
problem is in your application display file or code.

Regards,
Simon Coulter.
--------------------------------------------------------------------
   FlyByNight Software         OS/400, i5/OS Technical Specialists

   http://www.flybynight.com.au/
   Phone: +61 2 6657 8251   Mobile: +61 0411 091 400        /"\
   Fax:   +61 2 6657 8251                                   \ /
                                                             X
                 ASCII Ribbon campaign against HTML E-Mail  / \
--------------------------------------------------------------------