RE: *PRTCTL file

["Scott, Bill" <Bill.Scott@xxxxxxx>]

This code worked.Please note it is not mine, but from Midrange guru

     /* From http://www.itjungle.com/mgo/mgo101802-story01.html */
     
     Fspoolfile if   f  136        disk                      
     Fqsysprt   o    f  132        printer oflind(*inof)     
     F                                     prtctl(prtctlds)  
 
     D prtctlds        ds            15                      
     D  pSpaceBefore           1      3                      
     D  pSpaceAfter            4      6                      
     D  pSkipBefore            7      9                      
     D  pSkipAfter            10     12                      
     D  pLineNbr              13     15                      
                                                        
     D outputdata      s            132                      
                                                        
     Ispoolfile ns  01                                       
     I                                  1    3  sSkipBefore  
     I                                  4    4  sSpaceBefore 
     I                                  5  136  inputdata    
                                                        
     C                   read      spoolfile                  
     C                   dow       not %eof(spoolfile)        
     C                   eval      outputdata = inputdata     
     C                   if        sSkipBefore <> *blanks     
     C                   eval      pSkipBefore = sSkipBefore  
     C                   else                                 
     C                   eval      pSkipBefore = *blanks      
     C                   endif                                
     C                   if        sSpaceBefore <> *blanks    
     C                   eval      %subst(pSpaceBefore:3:1) = 
     C                                 sSpaceBefore           
     C                   else                                 
     C                   eval      pSpaceBefore = *blanks     
     C                   endif                                
     C                   except    lineout                    
     C                   read      spoolfile                  
     C                   enddo                                
     C                   eval      *inlr = *on                
     C                                              
     Oqsysprt   e            lineout                
     O                       outputdata         132 


Bill Scott
Océ North America, Inc.
Tel.: (561) 997-3256 
e-mail: Bill.Scott@xxxxxxx

-----Original Message-----
From: midrange-l-bounces@xxxxxxxxxxxx [mailto:midrange-l-bounces@xxxxxxxxxxxx] On Behalf Of rob@xxxxxxxxx
Sent: Thursday, October 08, 2009 10:13 
To: Midrange Systems Technical Discussion
Subject: Re: *PRTCTL file

Not off the top of my head but let's try to find out why you are doing it that way.  Is this supposed to be some sort of spool file save/restore? If so, then there's a different way to do this on supported versions of the operating system.

One method is to pipe it through a dummy output queue and then use the new SPLFDTA option SAVOBJ OBJ(MYOUTQ) 
       LIB(MYLIB) 
       DEV(*SAVF) 
       OBJTYPE(*OUTQ) 
       SAVF(MYLIB/MYSAVF) 
       SPLFDTA(*ALL) 


Rob Berendt