Re: Serial Terminal Emulator in IBM i i5/OS IBM i

[Scott Klement <midrange-l@xxxxxxxxxxxxxxxx>]

Hello,

Larry Bolhuis wrote:
> I seem to remember there was a command you could run on OS/400 back in 
> the day that would get you a rudimentary terminal emulator to a serial 
> port.

Like everyone else, I think you're probably referring to STRITF. 
(Though, it's not 36E, so maybe I'm wrong!)

Here's a CL program that I used to use with STRITF.  It's very old, and 
I've migrated hardware twice since the last time I used it, so I don't 
even know if it still works... (but it should, if you provide the right 
hardware resource!)

Perhaps it'll save you some time...

PGM

/* CREATE LINE DESCRIPTION */

LIND: CRTLINASC LIND(TERMLIN3) +
                RSRCNAME(LIN021) +
                ONLINE(*NO) +
                CNN(*SWTPP) +
                LINESPEED(19200) +
                SWTCNN(*DIAL) +
                AUTOANS(*NO) +
                AUTODIAL(*YES) +
                DIALCMD(*OTHER) +
                INACTTMR(*NOMAX) +
                TEXT('Async line description')
      MONMSG MSGID(CPF2718) EXEC(DO)
         DLTLIND LIND(TERMLIN3)
         MONMSG MSGID(CPF2633) EXEC(DO)
            VRYCFG CFGOBJ(TERMLIN3) CFGTYPE(*LIN) STATUS(*OFF)
         ENDDO
         GOTO LIND
      ENDDO


/* CREATE CONTROLLER DESCRIPTION */

CTLD: CRTCTLASC CTLD(TERMCTL3) +
                LINKTYPE(*ASYNC) +
                ONLINE(*NO) +
                SWITCHED(*YES) +
                SWTLINLST(TERMLIN3) +
                CNNNBR(1234) +
                TEXT('Async controller')
      MONMSG MSGID(CPF2716) EXEC(DO)
          DLTCTLD CTLD(TERMCTL3)
          MONMSG MSGID(CPF2615) EXEC(DO)
              VRYCFG CFGOBJ(TERMCTL3) CFGTYPE(*CTL) STATUS(*OFF)
           ENDDO
           GOTO CTLD
      ENDDO


/*  CREATE DEVICE DESCRIPTION */

DEVD: CRTDEVASC DEVD(TERMDEV3) +
                RMTLOCNAME(BBS) +
                ONLINE(*NO) +
                CTL(TERMCTL3) +
                TEXT('Async device description')
      MONMSG MSGID(CPF261A) EXEC(DO)
          DLTDEVD DEVD(TERMDEV3) /* DEVICE EXISTS */
          GOTO DEVD
      ENDDO


/*  VARY ON LINE DESCRIPTION */

   VRYCFG CFGOBJ(TERMLIN3) CFGTYPE(*LIN) STATUS(*ON)
   MONMSG MSGID(CPF2640)  EXEC(DO)
      SNDPGMMSG MSGID(CPD0006) MSGF(QCPFMSG) MSGTYPE(*ESCAPE) +
                MSGDTA('    Cannot vary on line. Giving up.')
      RETURN
   ENDDO


/*  VARY ON CONTROLLER & DEVICE DESCRIPTIONS */

   VRYCFG CFGOBJ(TERMCTL3) CFGTYPE(*CTL) STATUS(*ON)
   VRYCFG CFGOBJ(TERMDEV3) CFGTYPE(*DEV) STATUS(*ON)


/*  USE ITF TO CALL A BBS */

   STRITF RMTLOCNAME(BBS)
   MONMSG MSGID(CPF5138)


/* SESSION ENDED, VARY OFF THE LINE & CONTROLLER */

   VRYCFG CFGOBJ(TERMCTL3) CFGTYPE(*CTL) STATUS(*OFF)
   VRYCFG CFGOBJ(TERMLIN3) CFGTYPE(*LIN) STATUS(*OFF)


/* DELETE THE CONFIG OBJECTS WHEN NOT IN USE */

   DLTDEVD DEVD(TERMDEV3)
   DLTCTLD CTLD(TERMCTL3)
   DLTLIND LIND(TERMLIN3)

 ENDPGM