|
midrange.com
Hello Marcin,
Here you go:
**--------------------------------------------------------------------**
** **
** Compile options required: **
** DftActGrp( *NO ) + **
** ActGrp( QILE ) + **
** BndDir( QC2LE ) **
** **
**-- Parameters: -------------------------------------------------------**
D DtLil s 10i 0
**
D MsgId s 7a
D MsgHex s 4a
**
D Feedback Ds
D FB 10u 0
D MsgSev 5u 0 Overlay( FB: 1 )
D MsgNo 5u 0 Overlay( FB: 3 )
D Bits 1a
** Case :2
** Sev :3
** Ctl :3
D Facility_id 3a
D IS_Info 10u 0
**-- Date function: ----------------------------------------------------**
D CeeDays Pr ExtProc( 'CEEDAYS' ) OpDesc
D CdDatChr 32a Const Options( *VarSize )
D CdDatPic 32a Const Options( *VarSize )
D CdLilDat 10i 0
D CdFc 12a Options( *Omit )
**
D cvthc Pr * ExtProc( 'cvthc' )
D * Value
D * Value
D 10i 0 Value
**-- Convert: ----------------------------------------------------------**
**
C CallP CeeDays( '20001127'
C : 'YYYYDDMM'
C : DtLil
C : Feedback
C )
**
C If FB > *Zero
**
C CallP cvthc( %Addr( MsgHex )
C : %Addr( MsgNo )
C : %Size( MsgHex )
C )
C Eval MsgId = Facility_Id + MsgHex
C EndIf
**
C Return
**
Best regards,
Carsten
----- Original Message -----
From: <owner-rpg400-l@midrange.com>
To: <RPG400-L@midrange.com>
Sent: 27. november 2000 10:36
Subject: Re: Feedback ds for CEEDAYS API
Hi Carsten
As You suggested I run api in such way :
d Feedback ds
d MsgSev 5u 0
d MsgNo 5u 0
d Bits 1a
d** Case
d** Severity
d** Control
d Facilyty_id 3a
d I_S_Info 10u 0
d FB ds
d Fld 1 6p 0
d F_id 6 8a
d ISInfo 9 12p 0
c CallP CeeDays( '20001127'
c : 'YYYYDDMM'
c : DtLil
c : FB
c )
c MoveL FB FeedBack
Because days and month are mixed in date format I should get error
CEE2517 Sev 30. The value for month is not valid
Value of FB is
> EVAL FB
FLD OF FB = 003251759Ü.
F_ID OF FB = 'CEE'
ISINFO OF FB = 00001Ď.
I suppose FLD is consist on severity (003), number of message (2517) and
some other info (59Ü)
but when I move it to FeedBack data structure i get
> EVAL FeedBack
MSGSEV OF FEEDBACK = 3
MSGNO OF FEEDBACK = 9495
BITS OF FEEDBACK = 'ß'
FACILYTY_ID OF FEEDBACK = 'CEE'
I_S_INFO OF FEEDBACK = 418
and I lost proper number of message. This same situation I have had with my
old FeedBack ds.
Any suggestions. TIA
Regards
Marcin Sagan
>>> "Carsten Flensburg" <flensburg@novasol.dk> 11/24 8:11 >>>
Hello Marcin,
You just need to add the bitfields' storage:
d Feedback ds.
d MsgSev 5u 0
d MsgNo 5u 0
d Bits 1a
d** Case
d** Severity
d** Control
d Facilyty_id 3a
d I_S_Info 10u 0
Best regards,
Carsten Flensburg
----- Original Message -----
From: <owner-rpg400-l@midrange.com>
To: <RPG400-L@midrange.com>
Sent: Friday, November 24, 2000 2:34 PM
Subject: Feedback ds for CEEDAYS API
>
>
> Hi all
>
> How to define feedback data structure for CEEDAYS API?
> I have try unsuccessfully following the C definition
>
> * typedef volatile struct {
> * _UINT2 MsgSev;
> * _UINT2 MsgNo;
> * _BITS Case :2;
> * _BITS Severity :3;
> * _BITS Control :3;
> * _CHAR Facility_ID[3];
> * _UINT4 I_S_Info;
> * } _FEEDBACK;
>
> d Feedback ds.
> d MsgSev 5u 0
> d MsgNo 5u 0
> d** Case
> d** Severity
> d** Control
> d Facilyty_id 3a
> d I_S_Info 10u 0
>
> Regards
> Marcin Sagan
>
>
> !
> !
>
> +---
> | This is the RPG/400 Mailing List!
> | To submit a new message, send your mail to RPG400-L@midrange.com.
> | To subscribe to this list send email to RPG400-L-SUB@midrange.com.
> | To unsubscribe from this list send email to
RPG400-L-UNSUB@midrange.com.
> | Questions should be directed to the list owner/operator:
> david@midrange.com
> +---
>
+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator:
david@midrange.com
+---
+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator:
david@midrange.com
+---
+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---
As an Amazon Associate we earn from qualifying purchases.
This mailing list archive is Copyright 1997-2025 by midrange.com and David Gibbs as a compilation work. Use of the archive is restricted to research of a business or technical nature. Any other uses are prohibited. Full details are available on our policy page. If you have questions about this, please contact [javascript protected email address].
Operating expenses for this site are earned using the Amazon Associate program and Google Adsense.
