Re: MultiRow Fetch

["Rolf Mittag" <mailing-lists@xxxxxxxxxxxx>]

this works (at least for me ;-)). it's in a service program :

     c/Exec SQL
     c+   declare SDDXREP_C cursor for
     c+      select *
     c+         from DX_ExcludeFilter
     c+         where  CH_Token = :CH_Token
     c+            and D0_Token = :D0_Token
     c+         order by DF_Seq
     c/End-Exec

      ** ==================================================================== **
      ** fetchDX         : fetch next row from the cursor                     **
      ** -------------------------------------------------------------------- **
     pfetchDX          b                   export

     dfetchDX          pi                  like(RC_T)
     d dxCount                        3p 0
     d dxStrP                          *   value

     dsddxrep        e ds                  ExtName(sddxrep) occurs(999)
     d                                     based(dxStrP)

     ddummy            s               n

     c                   if        not openC

     c                   eval      dxCount = *zero
     c                   eval      rc = rcError

     c                   else

     c/Exec SQL
     c+   fetch next from SDDXREP_C for 999 rows
     c+      into :sddxrep
     c/End-Exec
     c                   eval      rc = chkSqlStt(SqlStt)

     c                   select

     c                   when      rc = rcOk
     c                   eval      dxCount = SqlEr3

     c                   when      rc = rcEof
     c                   eval      rc = rcOk
     c                   eval      dxCount = *zero

     c                   other
     c                   eval      dxCount = *zero
     c                   eval      TT_RetCde = Rc

     c                   endSl

     c                   eval      dummy = closeC
     c                   endIf

     c                   return    rc
     pfetchDX          e

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*
! Dipl.Inf.(FH) Rolf P Mittag  IBM Partner in Development     !
! Leipziger Str. 50            D-69214 Eppelheim              !
! Fon: +49 (6221) 76 78 60     Fax: +49 (6221) 76 80 26   /"\ !
! eMl: rm@r-m-e-d-v.de                                    \ / !
!                                                          X  !
!              ASCII Ribbon campaign against HTML E-Mail  / \ !
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*