Re: QUSROBJD API

["Luis Martins" <lnmartins@xxxxxxxxxxxx>]

Hello Carsten Flensburg,

Thank you very much for your tip, but there is one thing that
i don't understand in the statment :

     C                   If        AeBytAvl   >  *Zero         And
     C                             AeMsgId    =  'CPF9801'
     "If i have to put any instruction in this place it doesn't work"
     **-- Object doesn't exist...
     C                   EndIf


Thank You !

Luis Martins.





Please respond to RPG programming on the AS400 / iSeries
       <rpg400-l@xxxxxxxxxxxx>

Sent by:    rpg400-l-bounces@xxxxxxxxxxxx


To:    "RPG programming on the AS400 / iSeries" <rpg400-l@xxxxxxxxxxxx>
cc:
Subject:    Re: QUSROBJD API


     Hello Luis,

     Here's an RPG/IV sample:

     **-- Header specifications:
     --------------------------------------------**
     H Option( *SrcStmt )
     **-- Global variables:
     -------------------------------------------------**
     D ObjNam          s             10a
     D ObjLib          s             10a
     D ObjTyp          s             10a
     **-- Api error data structure:
     -----------------------------------------**
     D ApiError        Ds
     D  AeBytPro                     10i 0 Inz( %Size( ApiError ))
     D  AeBytAvl                     10i 0 Inz
     D  AeMsgId                       7a
     D                                1a
     D  AeMsgDta                    128a
     **-- Object description structure OBJD0100:
     ----------------------------**
     D RoData          Ds
     D  RoBytRtn                     10i 0
     D  RoBytAvl                     10i 0
     D  RoObjNam                     10a
     D  RoObjLib                     10a
     D  RoObjTypRt                   10a
     D  RoObjLibRt                   10a
     D  RoObjASP                     10i 0
     D  RoObjOwn                     10a
     D  RoObjDmn                      2a
     D  RoObjCrtDts                  13a
     D  RoObjChgDts                  13a
     D  RoExtAtr                     10a
     D  RoTxtDsc                     50a
     D  RoSrcF                       10a
     D  RoSrcLib                     10a
     D  RoSrcMbr                     10a
     **-- Retrieve object description:
     --------------------------------------**
     D RtvObjD         Pr                  ExtPgm( 'QUSROBJD' )
     D  RoRcvVar                  32767a         Options( *VarSize )
     D  RoRcvVarLen                  10i 0 Const
     D  RoFmtNam                      8a   Const
     D  RoObjNamQ                    20a   Const
     D  RoObjTyp                     10a   Const
     D  RoError                   32767a         Options( *VarSize )
     **
     **-- Get Web value:
     ----------------------------------------------------**
     **
     C                   Eval      ObjNam     =  '???'
     C                   Eval      ObjLib     =  '*LIBL'
     C                   Eval      ObjTyp     =  '*PGM'
     **
     C                   CallP     RtvObjD( RoData
     C                                    : %Size( RoData )
     C                                    : 'OBJD0100'
     C                                    : ObjNam + ObjLib
     C                                    : ObjTyp
     C                                    : ApiError
     C                                    )
     **
     C                   If        AeBytAvl   >  *Zero         And
     C                             AeMsgId    =  'CPF9801'
     **-- Object doesn't exist...
     C                   EndIf
     **
     C                   Return
     **

     Best regards,
     Carsten Flensburg


     ----- Original Message -----
     From: "Luis Martins" <lnmartins@xxxxxxxxxxxx>
     To: <rpg400-l@xxxxxxxxxxxx>
     Sent: Wednesday, August 06, 2003 9:51 AM
     Subject: QUSROBJD API


     Can any one tell me how can use this API (QUSROBJD)  to know if an
     object
     exist ?





     _______________________________________________
     This is the RPG programming on the AS400 / iSeries (RPG400-L) mailing
     list
     To post a message email: RPG400-L@xxxxxxxxxxxx
     To subscribe, unsubscribe, or change list options,
     visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
     or email: RPG400-L-request@xxxxxxxxxxxx
     Before posting, please take a moment to review the archives
     at http://archive.midrange.com/rpg400-l.



     __________________________________________________

     Esta mensagem e quaisquer ficheiros anexos são confidenciais,
     destinando-se ao uso exclusivo da pessoa e/ou entidade a que se
     dirigem. Caso não se lhe destine, ou não seja responsável pelo seu
     encaminhamento ao destinatário, informamos que a recebeu por engano.
     Qualquer utilização, distribuição, reencaminhamento ou outra forma de
     revelação a terceiros, impressão ou cópia são expressamente proibidos;
     sendo que agradecemos que destrua a mensagem de imediato, informando o
     seu emissor ou o Finibanco do sucedido. Não obstante o Finibanco
     utilizar software anti-vírus como precaução, não é possível garantir
     que a presente mensagem e eventuais ficheiros anexos não contêm vírus,
     pelo que não consideramos da responsabilidade desta instituição
     eventuais consequências inerentes. Alerta-se, ainda, que as mensagens
     transmitidas por este meio podem ser interceptadas, corrompidas,
     perdidas, destruídas ou entregues com atraso ao destinatário.