Re: FW: Have you seen this? An improved way.

[Mel Rothman <mel@xxxxxxxxxxxxxx>]

I found a better way to write your own subprocedure, one that doesn't require 
calling the subprocedure then assigning the value.  Here is the revised code:

The subprocedure's prototype:
D MyGetVar        pr                  opdesc
D  varname                      50          const varying options(*varsize)
D  varvalue                  32767          options(*varsize)
D  occurrence                   10i 0       const options(*nopass)

The subprocedure's implementation
P MyGetVar        b
D MyGetVar        pi                  opdesc
D  varname                      50          const varying options(*varsize)
D  varvalue                  32767          options(*varsize)
D  occurrence                   10i 0       const options(*nopass)

 * Work fields
D wk              s          32767    varying
D i               s             10i 0

 * Parameters for CEEDOD, get operational descriptors (CEEDOD is prototyped
 * in QRPGLESRC member PROTOTYPEB)
D  Parmnum        s             10i 0
D  DescType       s             10i 0
D  DataType       s             10i 0
D  DescInfo1      s             10i 0
D  DescInfo2      s             10i 0
D  InDataSize     s             10i 0

 * Set i to occurrence
C                   if        %parms < 3
C                   eval      i = 1
C                   else
C                   eval      i = occurrence
C                   endif
 * Get information about second parameter.  Will use InDataSize
C                   callp     ceedod(2:DescType:DataType:DescInfo1:
C                             DescInfo2:InDataSize:*omit)
 * Get value and assign to varvalue, but only for varvalue's actual length
C                   eval      wk = ZhbGetVar(varname:i)
C                   eval      %subst(varvalue:1:InDataSize) = wk
P MyGetVar        e

Sample uses:
C                   callp     mygetvar('custname':custname)
C                   callp     mygetvar('somevar':somevar:someoccur)

Mel Rothman, CGIDEV2 Author
Mel Rothman, Inc.