Re: CEE4RAGE - call-back procedure not being called

[Scott Klement <rpg400-l@xxxxxxxxxxxxxxxx>]

Hi Larry,

> I have a problem with a registered call-back procedure not being called when
> a named activation group is ended.
[SNIP]

I didn't see anything in your message that sounded wrong, except maybe
that maybe when you use ENDJOB *IMMED it's not giving it a chance to end?
I would suspect that *IMMED means "don't run anything else."

To try to reproduce the problems that you're having, I created the
following trivial program.  When I run it, nothing happens.  If I sign off
(thus ending the job) and sign back on again, I have the message "I like
pie" waiting in my message queue.

That implies to me that the message was sent as I was signing off.  Does
this also work on your system?

     H DFTACTGRP(*NO) ACTGRP('QILE')

     D myCallBackProc  PR
     D   AgMark                      10U 0 options(*nopass)
     D   Reason                      10U 0 options(*nopass)
     D   Result                      10U 0 options(*nopass)
     D   UserRC                      10U 0 options(*nopass)

     D myProcName      PR                  ExtProc('CEE4RAGE')
     D   procedure                     *   procptr const
     D   feedback                    12A   options(*omit)

     c                   callp     myProcName( %paddr(myCallBackProc)
     c                                       : *OMIT )
     c                   eval      *inlr = *on

     P myCallBackProc  B                   export
     D myCallBackProc  PI
     D   AgMark                      10U 0 options(*nopass)
     D   Reason                      10U 0 options(*nopass)
     D   Result                      10U 0 options(*nopass)
     D   UserRC                      10U 0 options(*nopass)

     D QCMDEXC         PR                  ExtPgm('QCMDEXC')
     D   cmd                        200A   const
     D   length                      15P 5 const

     c                   callp     QCMDEXC('SNDMSG MSG(''I like pie'') ' +
     c                                         'TOUSR(KLEMSCOT)': 200)

     P                 E