Re: EOFDLY problem

[Rich Duzenbury <rduz-midrange@xxxxxxxxxxxxxxxxxxx>]

On Fri, 2005-07-01 at 09:58 -0700, Mahesh Pawar wrote:
> I am using EOFDLY option in OVRDBF of PF and calling RPG program to process 
> the file. Itʼs works fine whenever there is at least one records in file. But 
> if my file is empty. Program doesnʼt wait for new records. 
Mahesh, 

EOFDLY has been working fine since system/38 days.  Your override isn't
correct, or your code isn't correct.

Look at this sample code.  I started the program with an empty file, and
it waited just like it was supposed to.  As I added records, it woke up
and received them, just like it was supposed to.


EOFDLYP, type PF
     A                                      UNIQUE
     A          R EOFDLY
     A            SEQ#           9P 0
     A          K SEQ#



EOFDLYC, type CLP
PGM

OVRDBF EOFDLYP EOFDLY(60)

CALL EOFDLYR

ENDPGM



EOFDLYR, type RPGLE
     Feofdlyp   if   e           k disk

     d msg             s             50

      /free
         read eofdlyp;
         dow NOT %eof(eofdlyp);
             // See if the job has been canceled
             if %shtdn;
                 leave;
             endif;

             msg = 'Got Record ' + %char(seq#);
             dsply msg;

             read eofdlyp;
         enddo;

         *inlr = '1';
      /end-free


Regards,
Rich