RE: Calling Java from RPG

[B.Quindt@xxxxxxxxxxxx]

Thanks to All,

with WDSC "LPEX Editor" I tried to get the Prototype with -> new -> "Java
Class call"
and I get a Source  like the following.


D*-------------------------------------------------------------------------
D* Parameter field declarations for Java method:
D*     main in class GeneratePDF
D*-------------------------------------------------------------------------
D* Parameter field declaration for Java type: String[]
D  JavaDir        S               O   DIM(32767)
D                                     CLASS(*JAVA : 'java.lang.String' )

D*---------------------------------------------------------
D* Prototype for Java method:
D*     main in class GeneratePDF in package com.softm.itext
D*---------------------------------------------------------
D  main           PR                  EXTPROC(*JAVA : 'com.softm.itext.G+
D                                     eneratePDF' : 'main' )
D                                     STATIC
D* Parameter prototype declaration for Java type: String[]
D  arg0                           O   DIM(32767)
D                                     CLASS(*JAVA : 'java.lang.String' )
D                                     CONST
D*---------------------------------------------------------


With some modifications like the following I get the Java Program running


D Dir             s            128a
 * ------------------------------------------- *
D createString    PR              O   EXTPROC(*JAVA
D                                     :'java.lang.String'
D                                     :*CONSTRUCTOR)
D                                     CLASS(*JAVA
D                                     :'java.lang.String')
D parm                         128    CONST VARYING
D*-------------------------------------------------------------------------
D* Parameter field declarations for Java method:
D*     main in class GeneratePDF
D*-------------------------------------------------------------------------
D* Parameter field declaration for Java type: String[]
D  JavaDir        S               O   CLASS(*JAVA : 'java.lang.String' )
D                                     DIM(1)
D*---------------------------------------------------------
D* Prototype for Java method:
D*     main in class GeneratePDF in package com.softm.itext
D*---------------------------------------------------------
D  CreatePDF      PR                  EXTPROC(*JAVA : 'com.softm.itext.G+
D                                     eneratePDF' : 'main' )
D                                     STATIC
D* Parameter prototype declaration for Java type: String[]
D                                 O   CLASS(*JAVA : 'java.lang.String' )
D                                     DIM(1)
D                                     CONST
       /FREE
       JavaDir(1) = CreateString( %TRIM(Dir) ) ;
       CreatePDF( JavaDir ) ;
       *INLR = *ON;
       return;
      /END-FREE

_____________________________________________________
Burkhard Quindt
email: b.quindt@xxxxxxxxxxxx
_____________________________________________________