"RPG400-L" <rpg400-l-bounces@xxxxxxxxxxxxxxxxxx> wrote on 02/22/2020
03:09:09 PM:
Am 20.02.2020 um 20:59 schrieb dlclark@xxxxxxxxxxxxxxxx:
So, if you don't have other record formats *inside* of the window
borders then you should probably create them and use OVERLAY KEEP on
them.
Then, you can write your two record formats with the window borders
just
once to reduce flicker. You can then read and (re)write the formats
with
OVERLAY KEEP without disturbing the formats with the window borders.
Okay, now I understood. Thanks!
Since every additional Window needs space for its border (even if it
is invisible), I opt to live with the flicker.
There should be *no* additional windows or borders (invisible or
otherwise). The record formats I referred to (that are *inside* the
format with the window borders) are not windows themselves and, therefore,
have no borders of their own (invisible or otherwise). They refer back to
the outer window format. I've included one of my WINDOW display files as
an example. This is a single window with 5 sub-record formats (function
keys, message control and its subfile, header control and its subfile)
within the single window. I could just as easily have had two
side-by-side windows (as in your case) -- each with 5 sub-record formats
within them.
A INDARA
A HELP(01 'Help') ALTHELP(CA01)
A CF02(02)
A CA03(03 'Exit')
A CF04(04)
A CF05(05)
A CF06(06)
A CF07(07)
A CF08(08)
A CF09(09)
A CF10(10)
A CF11(11)
A CA12(12 'Cancel')
A CF13(13)
A CF14(14)
A CF15(15)
A CF16(16)
A CF17(17)
A CF18(18)
A CF19(19)
A CF20(20)
A CF21(21)
A CF22(22)
A CF23(23)
A CF24(24)
A*
A
*------------------------------------------------------------------------*
A* Window border *
A
*------------------------------------------------------------------------*
A R ACSYAW2W TEXT('WINDOW RECORD')
A WINDOW(*DFT 17 43 *NOMSGLIN)
A WDWBORDER((*COLOR BLU))
A*
A
*------------------------------------------------------------------------*
A* Subfile Record *
A
*------------------------------------------------------------------------*
A R ACSYAW2S TEXT('SUBFILE RECORD')
A SFL
A 55 SFLNXTCHG
A S1ID R 20S 0H REFFLD(ACSYAPPTID ACSYAPPT)
A S1OPTH 2A H
A S1OPT 2A B 10 3
A COLOR(WHT)
A DSPATR(HI)
A 30 DSPATR(PC)
A S1APPCDE R O 10 8REFFLD(APPCDE ACSYAPPT)
A COLOR(GRN)
A S1APPNME R O 10 13REFFLD(APPNME ACSYAPPT)
A COLOR(GRN)
A*
A
*------------------------------------------------------------------------*
A* Subfile Control *
A
*------------------------------------------------------------------------*
A R ACSYAW2C TEXT('SUBFILE CONTROL RECORD')
A SFLCTL(ACSYAW2S)
A OVERLAY KEEP
A WINDOW(ACSYAW2W)
A SFLPAG(5)
A SFLSIZ(6)
A 50 SFLDSPCTL
A 51 SFLDSP
A 52 SFLEND(*MORE)
A 53 SFLCLR
A 54 SFLINZ
A RTNCSRLOC(*RECNAME &CSRRCD &CSRFLD
-
A &CSRPOS)
A SFLCSRRRN(&CSRRRN)
A SFLPOS 4S 0H SFLRCDNBR(*TOP)
A CSRRRN 5S 0H
A CSRRCD 10A H
A CSRFLD 10A H
A CSRPOS 4S 0H
A*
A 1 2'ACSYAW2C'
A COLOR(BLU)
A C1TIMEUSA T O 1 35COLOR(BLU)
A TIMFMT(*USA)
A 2 11'WISE Application Lookup'
A COLOR(WHT)
A DSPATR(HI)
A 4 2'Position to Code . .'
A COLOR(GRN)
A C1APPCDE R B 4 23REFFLD(APPCDE *LIBL/ACSYAPPT)
A DSPATR(HI)
A COLOR(WHT)
A 6 2'Type options, press Enter.'
A COLOR(BLU)
A C1OPTS 39 O 7 4
A COLOR(BLU)
A 9 7'Code'
A COLOR(WHT)
A DSPATR(UL)
A 9 13'Application name '
A COLOR(WHT)
A DSPATR(UL)
A 9 2'Opt'
A COLOR(WHT)
A DSPATR(UL)
A*
A
*------------------------------------------------------------------------*
A* Empty Subfile Message *
A
*------------------------------------------------------------------------*
A R NORECS TEXT('NO SUBFILE RECORDS')
A OVERLAY KEEP
A WINDOW(ACSYAW2W)
A N51 11 7'* No Applications to display *'
A COLOR(WHT)
A*
A
*------------------------------------------------------------------------*
A* Function Keys *
A
*------------------------------------------------------------------------*
A R ACSYAW2F TEXT('FUNCTION KEYS RECORD')
A OVERLAY KEEP
A WINDOW(ACSYAW2W)
A C1FUNCS 41 O 16 2
A COLOR(BLU)
A*
A
*------------------------------------------------------------------------*
A* Error Message Subfile and Control for Window *
A
*------------------------------------------------------------------------*
A R SMSFL TEXT('MESSAGE SUBFILE')
A SFL
A SFLMSGRCD(17)
A SFLMSGKEY SFLMSGKEY
A SFLMSGQUE SFLPGMQ
A*
A R SMSFLC TEXT('MESSAGE SUBFILE CONTROL')
A SFLCTL(SMSFL)
A SFLPAG(1)
A SFLSIZ(2)
A OVERLAY KEEP
A WINDOW(ACSYAW2W)
A SFLDSPCTL
A SFLDSP
A 58 SFLEND
A SFLINZ
A SFLMSGQUE SFLPGMQ
A*
A
*------------------------------------------------------------------------*
A* Dummy record format to prevent certain display errors *
A
*------------------------------------------------------------------------*
A R DUMMY TEXT('DUMMY DISPLAY RECORD')
A ASSUME
A 1 43' '
A*
Sincerely,
Dave Clark
midrange.com
