Re: Automatically killing long running jobs

["Brian Johnson" <brian.johnson.mn@xxxxxxxxx>]

Here's a minimalist implementation of Joe's idea:

/* Program: KILLER */
/* End a job if it exceeds it's maximum-allowed run duration */
pgm ( &job &user &number &seconds )
    dcl &job *char 10
    dcl &user *char 10
    dcl &number *char 6
    dcl &seconds *dec (15 5)
    dlyjob &seconds
    endjob &number/&user/&job option(*immed)
    monmsg CPF1321 /* Not found */
    monmsg CPF1362 /* Has completed */
    monmsg CPF1360 /* Already ending */
endpgm

/* Program: ROUTER */
/* Routing program to limit run duration of jobs */
/* Job queue QUSRNOMAX is assumed to be active, normally for subsystem
QUSRWRK */
/* Sample command to create the routing entry for this program: */
/*     ADDRTGE SBSD(QBATCH) SEQNBR(909) CMPVAL(KILLER) PGM(ROUTER) */
/* Sample command to submite a run-duration limited job: */
/*     SBMJOB CMD(...) RTGDTA(KILLER) */
pgm
    dcl &job *char 10
    dcl &user *char 10
    dcl &number *char 6
    dcl &seconds *dec (15 5) 600 /* Ten minutes */
    dcl &jobq *char 10 'QUSRNOMAX'
    rtvjoba &job &user &number
    sbmjob job( &job ) cmd( call killer ( &job &user &number &seconds
) ) jobq( &jobq )
    tfrctl qcmd
endpgm



On Nov 12, 2007 11:03 AM, Joe Pluta <joepluta@xxxxxxxxxxxxxxxxx> wrote:
> > From: Jim.McLean@xxxxxxxxxx
> >
> > Any ideas on how best to accomplish this?  Or am I off the mark in trying
> > this?
>
> Jim, just talking off the top of my head here, but maybe you could use a
> routing entry.  You could conceivably add a routing entry that performs
> three steps for every job that is submitted to the subsystem.